'Description: Read and get data from an Excel worksheet and 
'             display it from the first row until the fifth row
'             by using a MsgBox in Visual Basic 6.
'             Including the technique how you should access Excel 
'             step by step properly, from opening the Excel file until
'             close and clear the memory that used by Excel object.
'Author     : Masino Sinaga
'Date       : Sunday, August 2, 2009
'Preparation: 1. Create a new Standard exe project with 1 form
'             2. Add 1 CommandButton control on the Form1
'             3. Add an item "Microsoft Excel X.X Object Library"
'                from menu Project -> References... . X.X depends on
'                version Excel or Microsoft Office you are using.
'                When I tried this code, it had been installed 
'                Microsoft Office 2000 and Microsoft Office 2007,
'                thus, X.X above is equal with 12.0 which VB6
'                displaying only the last version object library Excel. 
'                In this case, Microsoft Excel 12.0 Object Library 
'             4. Ensure your Dataku.xls file already exists in the same
'                directory where your application located, and in
'                column B started from the first row until the fifth row
'                you already have value in it.
'             5. Copy the following code to the Form1 editor.
'------------------------------------------------------------------

Dim Excel As Excel.Application 'Excel Application
Dim ExcelWBk As Excel.Workbook 'Excel Workbook
Dim ExcelWS As Excel.Worksheet 'Excel Worksheet

Private Sub Command1_Click()
  On Error GoTo Err
  'Inisialitation Excel object
  StartExcel
  'Open Dataku.xls file that located in the same directory
  'where your application located.
  Set ExcelWBk = Excel.Workbooks.Open(App.Path & "\Dataku.xls")
  'Displaying its status on the form
  Print "Successfully open file ..."
  'Access the first Worksheet (1)
  'If you want to switch to the second Worksheet, then
  'simply replace (1) with (2), and so forth...
  Set ExcelWS = ExcelWBk.Worksheets(1)
  'Displaying its status on the form
  Print "Successfully read Worksheet Sheet1 ..."
  'Processing the ExcelWS variable
  With ExcelWS
    Dim i As Integer
    Dim strData As String
    'Read from the first row until the fifth row
    For i = 1 To 5
      'Assign to a variabel
      strData = strData & .Cells(i, 2) & vbCrLf
    Next i
  End With
  'Displaying the data to MsgBox
  MsgBox strData
  'After finished, don't forget to close the worksheet
  CloseWorkSheet
  'Displaying its status on the form
  Print "Successfully close worksheet and Excel file ..."
  'Don' forget neither, always clean-up the memory that
  'has just been used by Excel object
  ClearExcelMemory
  'Displaying its status on the form
  Print "Successfully clean-up the memory used by Excel ..."
  'Displaying the message
  MsgBox "Finish, that's all folks ...!", vbInformation, "Good"
  Exit Sub
Err:
  'CloseWorkSheet
  'When error occured, don't forget to clean-up the memory
  ClearExcelMemory
  MsgBox Err.Description, vbCritical, "Error Occured"
End Sub
 
Private Sub StartExcel()
  On Error GoTo Err:
  'First of all, get the Excel object, and if error occured
  'jumpt to the Err label on the bottom of this Sub,
  'then create the Excel object. Typically, error occured here
  'if the Excel object has not been created, yet
  Set Excel = GetObject(, "Excel.Application")
  Exit Sub
Err:
  'Create an Excel object if it does not exist.
  Set Excel = CreateObject("Excel.Application")
End Sub
 
Private Sub CloseWorkSheet()
  On Error Resume Next
  'Close the Excel workbook
  ExcelWBk.Close
  'Quit from Excel application
  Excel.Quit
End Sub
 
Private Sub ClearExcelMemory()
  'Clean-up the memory, check first, whether
  'the Excel object exists or not in the memory ...
  If Not ExcelWS Is Nothing Then Set ExcelWS = Nothing
  If Not ExcelWBk Is Nothing Then Set ExcelWBk = Nothing
  If Not Excel Is Nothing Then Set Excel = Nothing
End Sub

'Description: Calculate difference between 2 particular dates 
'             and show the result in format: day(s), hr:min:sec
'             For example: 
'             The first date  = 01/03/2002 17:18:00 and 
'             The second date = 01/09/2002 09:42:30, then
'             the result will output --> 183 day(s), 16:24:30 
'             (183 days, 16 hours, 24 minutes, and 30 seconds).
'             You can use the DateDiff function belongs to VB6
'Author     : Masino Sinaga 
'Created    : Sunday, September 1, 2002
'Preparation: 1. Create a new standar exe project with 1 Form.
'             2. Add controls: 2 TextBoxes, 1 Label, and 1 Timer.
'             3. Copy this following code to the form editor form.
'-------------------------------------------------------------------

Option Explicit
 
Function CalcDiff2Dates(ByVal d1 As Date, _
                        ByVal d2 As Date) As String
  Dim Second As Long, Day As Long, Hour As Long
  Dim CompleteHour As String
 
  If d1 > d2 Then
     MsgBox "The first date must be lower than " & _
            "the second date!", _
            vbCritical, "Warning"
     Exit Function
  End If
 
  'Count the difference in seconds
  Second = DateDiff("s", d1, d2)
 
  'Calculate the hour by dividing with 3600
  '(backslash ("\") in order to get the Integer
  'without decimal value)
  Hour = Second \ 3600
 
  'If hour greater than 23
  'it means: more than 1 day
  If Hour > 23 Then
 
     'Calculate day by dividing with 24
     '(backslash ("\") in order to get the Integer
     'value without decimal value)
     Day = Hour \ 24
 
     'Calculate the hour duration in hh:mm:ss
     CompleteHour = Format((d2 - d1), "hh:mm:ss")
 
  Else 'If the hour less than or equal with 23      

     Day = 0   'assign the Day with zero value      

     'Calculate hour duration in hh:mm:ss
     CompleteHour = Format((d2 - d1), "hh:mm:ss")
 
  End If  
 
  If Day = 0 Then  'If less than 1 day

     'Get the final result
     CalcDiff2Dates = CompleteHour
 
  Else  'If day greater than 0, show the day duration     

     'Get the final result
     CalcDiff2Dates = Day & " day(s), " & CompleteHour
 
  End If
 
  Exit Function
 
End Function
 
Private Sub Form_Load()
  Timer1.Interval = 500
  Timer1.Enabled = True
  Text1.Text = "01/03/2002 17:18:00"
  'Text2.Text = "01/09/2002 09:42:30"
  Text2.Text = Now
End Sub
 
Private Sub Timer1_Timer()
  On Error GoTo ErrHandler
  Text2.Text = Now
  Label1.Caption = CalcDiff2Dates(CDate(Text1.Text), _
                      CDate(Text2.Text))
  Exit Sub
ErrHandler:
  MsgBox "Invalid date or format!", _
         vbCritical, "Error Date"
End Sub

Option Explicit
 
Private Declare Function GetTimeZoneInformation Lib "KERNEL32.dll" (lpTimeZoneInformation As TIME_ZONE_INFORMATION) As Long
 
Private Type SYSTEMTIME
   wYear                As Integer
   wMonth               As Integer
   wDayOfWeek           As Integer
   wDay                 As Integer
   wHour                As Integer
   wMinute              As Integer
   wSecond              As Integer
   wMilliseconds        As Integer
End Type
 
Private Type TIME_ZONE_INFORMATION
   Bias                 As Long
   StandardName         As String * 64
   StandardDate         As SYSTEMTIME
   StandardBias         As Long
   DaylightName         As String * 64
   DaylightDate         As SYSTEMTIME
   DaylightBias         As Long
End Type
 
Private Const TIME_ZONE_ID_DAYLIGHT As Long = 2
Private Const Unix1970   As Long = 25569 'CDbl(DateSerial(1970, 1, 1))

Public Function Unix2Date(vUnixDate As Long, ByVal bReturnUTC As Boolean) As Date
   Unix2Date = DateAdd("s", vUnixDate, Unix1970) - IIf(bReturnUTC, 0, GetCurrentTZOffset)
End Function
 
Public Function GetCurrentTZOffset() As Double
   Dim tz               As TIME_ZONE_INFORMATION
   Dim lRet             As Long
   'Quickest way to see if we are in
   'Daylight savings is to check lRet
   lRet = GetTimeZoneInformation(tz)
   'Offset in minutes
   GetCurrentTZOffset = tz.Bias + IIf(lRet = TIME_ZONE_ID_DAYLIGHT, tz.DaylightBias, tz.StandardBias)
   GetCurrentTZOffset = GetCurrentTZOffset / 1440
End Function
 
Private Sub Command1_Click()
   MsgBox "UTC   = " & Unix2Date(1206980969, True) 'March 31, 2008 16:29:29 (UTC)
   MsgBox "Local = " & Unix2Date(1206980969, False) 'March 31, 2008 23:29:29 (UTC + 7)
End Sub

Public Function ConvertDateStringToDateValue()
  With Sheet1
    For i = 2 To 16000 'first row is the header column, so we start from the 2nd row
      If IsDate(.Cells(i, 7)) Then 'check whether the Date value in the 7th column
        'among those 16,000 rows, not all rows contain of the DateString
        'so, if the Cell value is a real Date, do nothing here...
      Else 'Else, if the cell value not a Date type
        'let's convert the Cell here, and put the result in to the 11th column
        .Cells(i, 11).Value = Format(CDate(.Cells(i, 7).Value), "yyyy-MM-dd")
      End If
    Next i
  End With
End Function